home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FFT / FFTR2C.ASM < prev    next >
Assembly Source File  |  1990-01-17  |  6KB  |  150 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Radix 2, In-Place, Decimation-In-Time FFT (fast).
  7. ; 
  8. ; Last Update 04 Feb 87   Version 1.2
  9. ;
  10. fftr2c  macro   points,data,coef
  11. fftr2c  ident   1,2
  12. ;
  13. ; Radix 2 Decimation in Time In-Place Fast Fourier Transform Routine
  14. ;
  15. ;    Complex input and output data
  16. ;        Real data in X memory
  17. ;        Imaginary data in Y memory
  18. ;    Normally ordered input data
  19. ;    Bit reversed output data
  20. ;       Coefficient lookup table
  21. ;        -Cosine values in X memory
  22. ;        -Sine values in Y memory
  23. ;
  24. ; Macro Call - fftr2c   points,data,coef
  25. ;
  26. ;       points     number of points (16-32768, power of 2)
  27. ;       data       start of data buffer
  28. ;       coef       start of sine/cosine table
  29. ;
  30. ; Alters Data ALU Registers
  31. ;       x1      x0      y1      y0
  32. ;       a2      a1      a0      a
  33. ;       b2      b1      b0      b
  34. ;
  35. ; Alters Address Registers
  36. ;       r0      n0      m0
  37. ;       r1      n1      m1
  38. ;               n2
  39. ;
  40. ;       r4      n4      m4
  41. ;       r5      n5      m5
  42. ;       r6      n6      m6
  43. ;
  44. ; Alters Program Control Registers
  45. ;       pc      sr
  46. ;
  47. ; Uses 6 locations on System Stack
  48. ;
  49. ; Latest Revision -  4-Feb-87
  50. ;
  51.         move    #data,r0        ;initialize input pointer
  52.         move    #points/4,n0    ;initialize butterflies per group
  53.         move    n0,n4           ;initialize pointer offsets
  54.         move    n0,n6           ;initialize coefficient offset
  55.         move    #points-1,m0    ;initialize address modifiers
  56.         move    m0,m1           ;for modulo(points) addressing
  57.         move    m0,m4
  58.         move    m0,m5
  59. ;
  60. ; Do first and second Radix 2 FFT passes
  61. ;
  62.         move            x:(r0)+n0,x0
  63.         tfr     x0,a    x:(r0)+n0,y1
  64.  
  65.         do      n0,_twopass
  66.         tfr     y1,b    x:(r0)+n0,y0
  67.         add     y0,a    x:(r0),x1                       ;ar+cr
  68.         add     x1,b    r0,r4                           ;br+dr
  69.         add     a,b     (r0)+n0                         ;ar'=(ar+cr)+(br+dr)
  70.         subl    b,a     b,x:(r0)+n0                     ;br'=(ar+cr)-(br+dr)
  71.         tfr     x0,a    a,x0            y:(r0),b
  72.         sub     y0,a                    y:(r4)+n4,y0    ;ar-cr
  73.         sub     y0,b    x0,x:(r0)                       ;bi-di
  74.         add     a,b                     y:(r0)+n0,x0    ;cr'=(ar-cr)+(bi-di)
  75.         subl    b,a     b,x:(r0)                        ;dr'=(ar-cr)-(bi-di)
  76.         tfr     x0,a    a,x0            y:(r4),b
  77.         add     y0,a                    y:(r0)+n0,y0    ;bi+di
  78.         add     y0,b    x0,x:(r0)+n0                    ;ai+ci
  79.         add     b,a                     y:(r0)+,x0      ;ai'=(ai+ci)+(bi+di)
  80.         subl    a,b                     a,y:(r4)+n4     ;bi'=(ai+ci)-(bi+di)
  81.         tfr     x0,a                    b,y:(r4)+n4
  82.         sub     y0,a    x1,b                            ;ai-ci
  83.         sub     y1,b    x:(r0)+n0,x0                    ;dr-br
  84.         add     a,b     x:(r0)+n0,y1                    ;ci'=(ai-ci)+(dr-br)
  85.         subl    b,a                     b,y:(r4)+n4     ;di'=(ai-ci)-(dr-br)
  86.         tfr     x0,a                    a,y:(r4)+
  87. _twopass
  88. ;
  89. ; Do all FFT passes but first, second and last pass
  90. ;
  91.         move    #points/8,n0    ;initialize butterflies per group
  92.         move    #4,n2           ;initialize groups per pass
  93.         move    #0,m6           ;initialize coefficient address modifier
  94.                                 ;for reverse carry (bit reversed) addressing
  95.  
  96.         do      #@cvi(@log(points)/@log(2)-2.5),_end_pass
  97.         move    #data,r0                ;initialize A input pointer
  98.         move    r0,r4                   ;initialize A output pointer
  99.         lua     (r0)+n0,r1      ;initialize B input pointer
  100.         move    #coef,r6        ;initialize C input pointer
  101.         lua     (r1)-,r5        ;initialize B output pointer
  102.         move    n0,n1           ;initialize pointer offsets
  103.         move    n0,n4
  104.         move    n0,n5
  105.  
  106.         do      n2,_end_grp
  107.         move    x:(r1),x1       y:(r6),y0       ;lookup -sine value
  108.         move    x:(r5),a        y:(r0),b
  109.         move    x:(r6)+n6,x0            ;lookup -cosine value
  110.  
  111.  
  112.         do      n0,_end_bfy    ;Radix 2 DIT butterfly kernel with constant
  113.         mac     x1,y0,b                         y:(r1)+,y1    ;twiddle factor
  114.         macr    -x0,y1,b        a,x:(r5)+       y:(r0),a
  115.         subl    b,a             x:(r0),b        b,y:(r4)
  116.         mac     -x1,x0,b        x:(r0)+,a       a,y:(r5)
  117.         macr    -y1,y0,b        x:(r1),x1
  118.         subl    b,a             b,x:(r4)+       y:(r0),b
  119. _end_bfy
  120.         move    a,x:(r5)+n5     y:(r1)+n1,y1    ;dummy load of x1 and y1
  121.         move    x:(r0)+n0,x1    y:(r4)+n4,y1
  122. _end_grp
  123.         move    n0,b1
  124.         lsr     b       n2,a1   ;divide butterflies per group by two
  125.         lsl     a       b1,n0   ;multiply groups per pass by two
  126.         move            a1,n2
  127. _end_pass
  128. ;
  129. ; Do last FFT pass
  130. ;
  131.         move    n1,n0           ;correct pointer offset for last pass
  132.         move    #data,r0        ;initialize A input pointer
  133.         move    r0,r4           ;initialize A output pointer
  134.         lua     (r0)+,r1        ;initialize B input pointer
  135.         move    #coef,r6        ;initialize C input pointer
  136.         lua     (r1)-n1,r5      ;initialize B output pointer
  137.         move    x:(r1),x1       y:(r6),y0
  138.         move    x:(r5),a        y:(r0),b
  139.  
  140.         do      n2,_lastpass    ;Radix 2 DIT butterfly kernel with one
  141.         mac     x1,y0,b x:(r6)+n6,x0    y:(r1)+n1,y1    ;butterfly per group
  142.         macr    -x0,y1,b        a,x:(r5)+n5     y:(r0),a
  143.         subl    b,a     x:(r0),b        b,y:(r4)
  144.         mac     -x1,x0,b        x:(r0)+n0,a     a,y:(r5)
  145.         macr    -y1,y0,b        x:(r1),x1       y:(r6),y0
  146.         subl    b,a             b,x:(r4)+n4     y:(r0),b
  147. _lastpass
  148.         move    a,x:(r5)+n5
  149.         endm
  150.